СП310+пр200

[EFrol]

Спасибо за подсказки.
Собственно говоря я уже это читал, просто некотрые моменты не понятны (учился давно по другой специальности (ТМС) и тогда комп был редкость. Проги писали на Фортране на листочке и сдавали преподу, а он окидывал взглядом и выносил вердикт - будет работать или нет).

Цель моих действий сделать ФБ который будет осуществлять следующий алгоритм: вращение вперёд-пауза-вращение назад и всё это повторять в течении определённого времени.
Делаю это для общего развития. На стандартных ФБ из овенлоджика уже сделано, теперь хочу освоить хотя бы в общих чертах ST. Привязаться хочу к функции DT потому как делала в ОЛ на BLINK и CTN и столкнулся с тем, что на длительных выдержках время уходит от встроенных часов из за конечной скорости работы программы. Приходилось вводить коррекцию.

Предлагаю взять этот пример за основу и доработать под Ваши желания:
Owen.jpg

function_block FPRP

    var_input
       OnOff : bool;    // Управление блоком
    end_var

    var_output
       FW, RW : bool;   // Сигналы вперед и назад
    end_var

    var
       State : udint;   // Текущее состояние
       t : udint;       // Метка времени события в мс
    end_var

    if OnOff then
        case State of
            0:  // Пауза 1 сек перед пуском вперед
                if time_to_udint(get_time()) - t >= 1000 then
                    State := 1; FW := true; RW := false; t := time_to_udint(get_time());    // Пуск вперед
                end_if
            1:  // Вращение вперед 2 сек перед паузой
                if time_to_udint(get_time()) - t >= 2000 then
                    State := 2; FW := false; RW := false; t := time_to_udint(get_time());   // Пауза
                end_if
            2:  // Пауза 1 сек перед пуском назад
                if time_to_udint(get_time()) - t >= 1000 then
                    State := 3; FW := false; RW := true; t := time_to_udint(get_time());    // Пуск назад
                end_if
            3:  // Вращение назад 2 сек перед паузой
                if time_to_udint(get_time()) - t >= 2000 then
                    State := 0; FW := false; RW := false; t := time_to_udint(get_time());   // Пауза
                end_if
        end_case
    else
        FW := false; RW := false; State := 0; t := 0;
    end_if
end_function_block

[Валенок]

почему не просто
t : time;
?

вангую что в else тоже
t := time_to_udint(get_time());

[EFrol]

почему не просто
t : time;
?

вангую что в else тоже
t := time_to_udint(get_time());

Хорошо. Как скажите:

function_block FPRP

    var_input
       OnOff : bool;    // Управление блоком
    end_var

    var_output
       FW, RW : bool;   // Сигналы вперед и назад
    end_var

    var
       State : udint;   // Текущее состояние
       t : time;        // Метка времени события
    end_var

    if OnOff then
        case State of
            0:  // Пауза 1 сек перед пуском вперед
                if get_time() - t >= T#1s then
                    State := 1; FW := true; t := get_time();    // Пуск вперед
                end_if
            1:  // Вращение вперед 2 сек перед паузой
                if get_time() - t >= T#2s then
                    State := 2; FW := false; t := get_time();   // Пауза
                end_if
            2:  // Пауза 1 сек перед пуском назад
                if get_time() - t >= T#1s then
                    State := 3; RW := true; t := get_time();    // Пуск назад
                end_if
            3:  // Вращение назад 2 сек перед паузой
                if get_time() - t >= T#2s then
                    State := 0; RW := false; t := get_time();   // Пауза
                end_if
        end_case
    else
        FW := false; RW := false; State := 0; t := T#0s;
    end_if
end_function_block

[Валенок]

Хорошо. Как скажите:

где ж хорошо ? time - это просто дело вкуса не принципиальное, а в else - кранты потенциальные

[EFrol]

где ж хорошо ? time - это просто дело вкуса не принципиальное, а в else - кранты потенциальные

Сейчас весь мир на пороге "крантов потенциальных"!

[Viktor D]

Ну в принципе я так делаю.

Time_1 := GET_DATE_TIME();
    curr_t := DT_TO_UDINT (Time_1);
    
    
    
    if strt then
        trgt_t := curr_t + ust;
     end_if
     
     if trgt_t <= curr_t  then
        out_dsb := true;
        out_enb := false;
        else
        out_dsb := false;
        out_enb := true;
     end_if

Это просто выдержка времени привязанная к секундам.

Насчёт точности - сравнивал время насчитанное моим макросом в пр с временем панели сп310. Там было расхождение. Опять же сейчас я не решаю какую то конкретную задачу, а учусь писать код на ST. Ну естественно надо что то конкретное делать - вот и практикуюсь.

[Viktor D]

За пример спасибо - буду разбираться.

[Валенок]

Сейчас весь мир на пороге "крантов потенциальных"!

Дык шаг 0 после стопа будет 1 цикл или 1.5 месяца же - как звезды сложатся

[EFrol]

Дык шаг 0 после стопа будет 1 цикл или 1.5 месяца же - как звезды сложатся

Вы хотите сказать, что get_time() - T#0s будет < T#1s в течении 1.5 месяцев?
Я думал, Вас беспокоит, что при быстром сбросе OnOff при State := 3; произойдет смена вращения без паузы.
А вообще, я бы с Вами согласился, если бы арифметика была бы со знаком!!!
Давайте предупредим новичков, что get_time() каждые 1.5 месяца обнуляется.
И да, при get_time() = Tmax, какое-то состояние будет выдержано не полностью.

Предлагаю безопасный вариант с предварительной паузой:

function_block FPRP

    var_input
       OnOff : bool;    // Управление блоком
    end_var

    var_output
       FW, RW : bool;   // Сигналы вперед и назад
    end_var

    var
       State : udint;   // Текущее состояние
       t : SYS.TON;     // Таймер
    end_var

    if OnOff then
        case State of
            0:  // Пауза 1 сек перед пуском вперед
                t(I:=true, T:=T#1s);
                if t.Q then
                    State := 1; FW := true; t(I:=false);    // Пуск вперед
                end_if
            1:  // Вращение вперед 2 сек перед паузой
                t(I:=true, T:=T#2s);
                if t.Q then
                    State := 2; FW := false; t(I:=false);   // Пауза
                end_if
            2:  // Пауза 1 сек перед пуском назад
                t(I:=true, T:=T#1s);
                if t.Q then
                    State := 3; RW := true; t(I:=false);    // Пуск назад
                end_if
            3:  // Вращение назад 2 сек перед паузой
                t(I:=true, T:=T#2s);
                if t.Q then
                    State := 0; RW := false; t(I:=false);   // Пауза
                end_if
        end_case
    else
        FW := false; RW := false; State := 0; t(I:=false);
    end_if
end_function_block

[Валенок]

Вы хотите сказать, что get_time() - T#0s будет < T#1s в течении 1.5 месяцев?
Я думал, Вас беспокоит, что при быстром сбросе OnOff при State := 3; произойдет смена вращения без паузы.

Не. С 1.5мес я погорячился. Не в этом случае.

Потенциальный крантец (в старом варианте) остается из-за практически всегда отсутствия задержки шага 0 после подъема OnOff.
При шаблонном использовании такой конструкции в шаге 0 могут быть какие-то подготовительные действия которые пойдут лесом. Смысл в таймере шага 0?
TON тут не причем, простое t := get_time(); (а не := 0) в else эту проблему решает.


Ну и лично я (дело вкуса) предпочитаю выходы привязывать не в шаге, а к шагу

..
end_case
FW := State = 1;
RW := State = 3;

Там где есть ENUM это максимально наглядно, да и здесь чуть очевидней.

А когда шагов много, еще и

..
end_case
if State <> State_ then //State_  - прошлое значение
  State_ := State;
  t := get_time();
end_if

Т.е. самовзвод таймера шагов после любого перехода. Но это норм когда само состояние OnOff = false тоже шаг, а не IF (внешний if для case не использую)