Замер времени

[Тугарин]

Здравствуйте, имеется ПЛК 110-60, есть два дискретных входа (подключены индуктивные датчики), необходимо замереть время прохождения расстояния, расстояние между конечными выключателями 300 см, это необходимо сделать для замера скорости перемещения, по формуле скорость= расстояние/время, я хочу высчитать этот интервал...........при помощи какой функций это можно осуществить??? Спасибо в заранее. При этом таймер необходимо сбрасывать и запускать по команде дискретного входа.

[spectrum48k]

наваял и себе и людям))
вроде работает.
секундомер Вам в руки)

FUNCTION_BLOCK P1P2MTRS
(*порядок датчиков не имеет значения*)
VAR_INPUT
	iDi1 : BOOL;			(*Вход датчик 1*)
	iDi2 : BOOL;			(*Вход датчик 2*)
	iRes : BOOL;			(*Сброс / запрет работы*)
	iMtrsSP : REAL;		(*Расстояние датчик1-датчик2, м*)
	iErrSP : TIME;			(*Время на ожидание второго датчика*)
END_VAR
VAR_OUTPUT
	oDone : BOOL;		(*Расчет выполнен, =TRUE только 1 цикл*)
	oErr : BOOL;			(*Ошибка: нет сигнала второго датчика*)
	oSpd : REAL;			(*Расчетная скорость, м/с*)
END_VAR
VAR
	Trig1: BOOL;
	Trig2 : BOOL;
	Trig :BOOL;
	TimeTrig : TIME;
	TDelta : TIME;
	Init: BOOL;
	Di1Old :BOOL;
	Di2Old : BOOL;
END_VAR



IF iRes THEN Init := oErr := FALSE; END_IF
IF oErr THEN RETURN; END_IF

(*INIT*)
IF NOT Init THEN
				Init := TRUE;
				Di1Old := iDi1;
				Di2Old := iDi2;
				iRes := oDone := Trig1:= Trig2 := Trig := FALSE;
				TimeTrig := TDelta := t#0ms;
				oSpd := 0;
END_IF

oDone := FALSE;

IF iDi1 > Di1Old THEN Trig1 := TRUE; END_IF
IF iDi2 > Di2Old THEN Trig2 := TRUE; END_IF

Di1Old := iDi1;
Di2Old := iDi2;


IF Trig1 OR Trig2 THEN
							IF NOT Trig THEN TimeTrig := TIME(); Trig := TRUE; END_IF
							TDelta := TIME() - TimeTrig;
							IF TDelta > iErrSP THEN oSpd := 0; oErr := TRUE; RETURN; END_IF


							IF Trig1 AND Trig2 THEN
														IF TDelta < t#10ms THEN oSpd := 0; oErr := TRUE; RETURN; END_IF
														oSpd := iMtrsSP * 1000 / TIME_TO_REAL(TDelta);
														oDone := TRUE;
														Trig1 := Trig2 := Trig := FALSE;
							END_IF
END_IF

[spectrum48k]

Сергей, не поверите)) Я взял таймер и TIME() Для двух разных целей. А во время отладки случайно заметил, что внутренние переменные таймера совпадают с результатами от TIME() и по сути выполняется дублирование переменных. Поэтому остался один таймер, выполняющий 2 функции сразу.

[spectrum48k]

Вы и мёртвого убедите) Сарказм засчитан.

[Тугарин]

Извините за наглость..............но я не знаю этот язык,к сожалению, знаю FBD,LD,CFC............ кто то сможет помочь и показать эту программу на одном из указанных языков???

[petera]

Извините за наглость..............но я не знаю этот язык,к сожалению, знаю FBD,LD,CFC............ кто то сможет помочь и показать эту программу на одном из указанных языков???

А почему SFC нет в этом перечне?
Захват-3.png

Захват-2.png
Специально для Вас действия для шага Spep2 сделал на CFC

[Тугарин]

Спасибо большое, буду пробовать, SFC не успеваю изучить, работы много.....не получается пока что CODESYS освоить полностью, обычно проекты на базе контроллера DELTA делаю, с ними как то попроще всё)

[petera]

По просьбе трудящихся тоже самое, но на LD
Захват-1.png

Захват-2.png

[spectrum48k]

Я дал текст для копирования/вставки. Знания языка ST не обязательны. Минимальные знания интерфейса CDS v2.3 - обязательны.
Будет выглядеть в CFC примерно так:


Вот файл. Разархивируете и просто импортируете его в дерево POU. Появится функциональный блок. Использовать его как на картинке примера, только замените имена тестовых переменных на свои.

[ВЗМП]

вопрос почти по теме - а что делает функция time? при вызове берет текущее время плк?
имеет ли смысл написанное ниже?

var
a:time;
end_var
a:=TIME;