Библиотеки сторонних разработчиков

[Эдуард_Н]

Не получаеться выделить из библиотеки OSCATBasic блок "ONTIME", ругается на переменную. Подскажите, что делать?

[petera]

Не получаеться выделить из библиотеки OSCATBasic блок "ONTIME", ругается на переменную. Подскажите, что делать?

Добавить эту переменную.
Для работы блока ONTIME нужна функция T_PLC_MS из этой же библиотеки. Или исправить одну сточку в коде ФБ

FUNCTION_BLOCK ONTIME
VAR_INPUT
    IN : BOOL;
    RST : BOOL;
END_VAR
VAR_IN_OUT
    SECONDS : UDINT;
    CYCLES : UDINT;
END_VAR
VAR
    tx: DWORD;
    last : DWORD;
    edge : BOOL;
    init: BOOL;
    ms: DWORD;
END_VAR

(* read system time *)
tx := TIME_TO_DWORD(TIME());

(* make sure the first cycle works correctly *)
IF NOT init THEN
    init := TRUE;
    last := tx;
    ms := 0;
END_IF;
IF RST THEN
    SECONDS := 0;
    CYCLES := 0;
    last := tx;
    ms := 0;
ELSIF IN THEN
    (* add the current milliseconds *)
    ms := (tx - last) + ms;
    IF ms >= 1000 THEN
  seconds := seconds + 1;
  ms := ms - 1000;
    END_IF;
    cycles := cycles + BOOL_TO_UINT(NOT edge);
END_IF;
last := tx;
edge := in;

[Эдуард_Н]

Спасибо, понял.

[Egerenok]

Нужна помощь: необходимо отследить время с момента выключения ПЛК160 до его включения. (* Не выключать ПЛК по ряду причин нельзя *).

[petera]

PROGRAM PLC_PRG
VAR
    Init: BOOL;
    Diff: TIME;    (*Время простоя ПЛК*)
    now: DT;    (*Текущие дата и время*)
END_VAR
VAR RETAIN
    old: DT;    (*Дата и время в момент откл ПЛК*)
END_VAR

now:=curDT();
IF NOT Init THEN    (*Если первый цикл ПЛК*)
    Diff:=now-old;    (*Время простоя ПЛК*)
    Init:=TRUE;
END_IF
old:=now;

Время простоя ПЛК (Diff: TIME) будет с дискретностью 1 секунда
Функцию curDT()

Код:

FUNCTION curDT : DT (* Дата и время в формате POSIX как число секунд с 0 часов 1 января 1970г*)
VAR_INPUT
END_VAR
VAR
    CurTimeExInst: CurTimeEx;
    CurSystemTimeDate: SystemTimeDate;
    CurSysTime64: SysTime64;
    year: INT;
    second: INT;
    day: INT;
    hour: INT;
    minute: INT;
    month: INT;
    count: INT;
    SET_DATE: DWORD;
END_VAR
CurTimeExInst(TimeDate := CurSystemTimeDate, SystemTime := CurSysTime64);
    year :=CurSystemTimeDate.Year;
    month :=CurSystemTimeDate.Month;
    day :=CurSystemTimeDate.Day;
    hour :=CurSystemTimeDate.Hour;
    minute :=CurSystemTimeDate.Minute;
    second :=CurSystemTimeDate.Second;
(*------------------------------------------------------------------------*)
(*Вычислить дату с учетом високосных лет*)
IF month > 2 THEN
    count := (month - 1) * 30;
    IF month > 7 THEN count := count + SHR(month - 3,1);
ELSE count := count + SHR(month - 4,1); END_IF;
    (* chech for leap year and add one day if true *)
    IF SHL(year,14) = 0 THEN count := count + 1; END_IF;
ELSE
    count := (month - 1) * 31;
END_IF;
SET_DATE := (INT_TO_DWORD(count + day - 1)
               + SHR(INT_TO_DWORD(year) * 1461 - 2878169, 2)) * 86400;
(*------------------------------------------------------------------------*)
curDT := DWORD_TO_DT(SET_DATE
              + INT_TO_DWORD(SECOND) + INT_TO_DWORD(MINUTE) * 60
              + INT_TO_DWORD(HOUR) * 3600);

"слепил" из OSCAT-овских SET_DT() и SET_DATE() http://www.owen.ru/forum/showthread....l=1#post161139
Используется стандартная SysLibTime.
Только часы ПЛК160 в выключенном состоянии сбрасываются через 5 суток и по истечение этого периода, время простоя ПЛК будет не корректным.