Подсчет мгновенного расхода жидкости от импульсов.

[petera]

Думаю, проблема в погрешности расчета времени цикла.
Попробуйте время цикла посчитать так

function_block TimeCycle
    
    var_input
        none : bool;
    end_var
    
    var_output 
        Q : udint;
    end_var
    
    var 
        init : bool;
        t1, t2 : udint;
    end_var
    
    t1 := time_to_udint(get_time());
    if init then
        Q := t1 - t2;
    else
        init := true;
    end_if
    t2 := t1;

end_function_block

Проще сразу на ST мгновенный расход вычислять, время цикла не нужно вообще
Простейший вариант

function_block RASHOD_lite   (* (с) PeterA для форума ОВЕН *) 
    var_input
        TIC: BOOL;        (*импульс счетчика*)
        Cimp: REAL;       (*Вес импульса, л*)
    end_var
    
    var_output 
        Q: REAL;        (*мгновенный расход мкуб/час*)
    end_var
    
    var 
        M: BOOL;
        period: TIME;
        start: TIME;
    end_var

IF TIC AND NOT M THEN
    period:= GET_TIME() - start;
    start:= GET_TIME();
END_IF
M:= TIC;
Q:= 3600/udint_to_real(time_to_udint(period)) * Cimp;
end_function_block

Более продвинутый вариант - с учетом параметра расходомера Qмин (Минимальный расход) см.ниже
https://owen.ru/forum/showthread.php...l=1#post470767

Захват-11.png

[kondor3000]

Проще сразу на ST мгновенный расход вычислять, время цикла не нужно вообще
Более продвинутый вариант - с учетом параметра расходомера Qмин (Минимальный расход)

Более продвинутый вариант не работает 1 Расход.jpg

[petera]

Более продвинутый вариант не работает 1 Расход.jpg

Спасибо,
Достаточно было опрометчиво переместить одну строчку, в начало IF и всё...
Правильный код

function_block RASHOD_Ex   (* (с) PeterA для форума ОВЕН *) 

    var_input
        TIC: BOOL;        (*импульс счетчика*)
        Cimp: REAL;       (*Вес импульса, л*)
        Qmin: REAL;        (*Минимальный расход м.куб/час*)
    end_var
    
    var_output 
        Q: REAL;        (*мгновенный расход мкуб/час*)
        overflow: BOOL;        (*Нет расхода (период импульсов больше максимального)*)
    end_var
    
    var 
        M: BOOL;
        period: TIME;
        start: TIME;
        INIT: BOOL;        (*пришел первый, начальный импульс, последовательности*)
        cur_TIME: TIME;    (*текущее время*)
        period2: TIME;     (*сколько прошло времени от фронта импульса*)
    end_var

cur_TIME:= GET_TIME();
IF TIC AND NOT M THEN    (*если фронт импульса*)
(* Было тут period2:=cur_TIME- start; *)
    IF NOT INIT THEN        (*если зто первый импульс*)
        INIT:= TRUE;        (*начинаем подсчет времени до фронта следующего импульса*)
        Q:= 0;              (* а пока расход = 0*)
    ELSE                    (*если не первый импульс, то*)
        period:= cur_TIME - start;    (*время между импульсами*)
        Q:= 3600/udint_to_real(time_to_udint(period)) * Cimp;        (*мгновенный расход*)
        overflow:= FALSE;    (*переполнения по времени между импульсами нет*)
    END_IF
start:= cur_TIME;            (*фиксация времени прихода фронта импульса*)    
END_IF
M:= TIC;                    (*пришел фронт импульса*)
period2:=cur_TIME- start;    (*сколько прошло времени от фронта последнего импульса*)
IF period2 >= udint_to_time(real_to_udint(3600 * Cimp / Qmin)) THEN (*если от фронта последнего импульса прошло время больше допустимого по Qmin*)
    Q:=0;                    (*значит нет расхода*)
    INIT:= FALSE;            (*следующий импульс будет первым*)
    overflow:= TRUE;         (*флаг переполнения по времени между импульсами*)
END_IF

end_function_block

[Sam92]

Проще сразу на ST мгновенный расход вычислять, время цикла не нужно вообще
Простейший вариант

function_block RASHOD_lite   (* (с) PeterA для форума ОВЕН *) 
    var_input
        TIC: BOOL;        (*импульс счетчика*)
        Cimp: REAL;       (*Вес импульса, л*)
    end_var
    
    var_output 
        Q: REAL;        (*мгновенный расход мкуб/час*)
    end_var
    
    var 
        M: BOOL;
        period: TIME;
        start: TIME;
    end_var

IF TIC AND NOT M THEN
    period:= GET_TIME() - start;
    start:= GET_TIME();
END_IF
M:= TIC;
Q:= 3600/udint_to_real(time_to_udint(period)) * Cimp;
end_function_block

Более продвинутый вариант - с учетом параметра расходомера Qмин (Минимальный расход) см.ниже
https://owen.ru/forum/showthread.php...l=1#post470767

Захват-11.png

Благодарю за код на ST - всё прекрасно работает!